1000 ' WSAI微気象情報処理PROG. VER.0.04 for N88BASIC
1010 '  和歌山農業情報利用研究会-144&tmine 99/01/10 12:00
1020 '  VER.0.01 98/12/26 23:32 WSAI-DATA LOGGER I/F部評価
1030 '  VER.0.02 99/01/06 07:43 CSV出力部評価
1040 '  VER.0.03 99/01/08 07:35 INFOMATION FILE/RENAME部評価
1050 '  VER.0.04 99/01/09 00:00 BECKY I/F部評価
1060 '  VER.0.04_N88 99/01/10 12:00 一応N88BASIC用へ変更 by tmine
2000 '初期化
2010  CLOSE
2020 'BAUD 1,9600:'  BAUD RATE 9600BPS  N88-Basicではサポートされてません(と思う)
2030  OPEN "c:\log\WLOG.INF" FOR INPUT AS #3   '適当なディレクトリを指定すること
2040  LINE INPUT #3,NUL0$
2050  LINE INPUT #3,PRT0$
2060  LINE INPUT #3,NUL0$
2070  LINE INPUT #3,DIF0$
2080  LINE INPUT #3,NUL0$
2090  LINE INPUT #3,PRD0$
2100  LINE INPUT #3,NUL0$
2110  LINE INPUT #3,HED0$
2120  LINE INPUT #3,NUL0$
2130  LINE INPUT #3,CSV0$
2140  LINE INPUT #3,NUL0$
2150  LINE INPUT #3,BCY0$
2160  LINE INPUT #3,NUL0$
2170  LINE INPUT #3,DN80$
2180  LINE INPUT #3,NUL0$
2190  LINE INPUT #3,MFR0$
2200  LINE INPUT #3,NUL0$
2210  CT01%=0:NUL0$=""
2220 ' 
2221 DIM MTO0$(9999), MBD0$(9999)   '一応余裕を持って配列を宣言（無宣言のときは添字は10まで）
2230  *LP1
2231   LINE INPUT #3,NUL0$
2240   IF INSTR(NUL0$,"[")>0 THEN *NEXT1
2250   MTO0$(CT01%)=NUL0$
2260   CT01%=CT01%+1
2270  GOTO *LP1    'DO ... LOOP 文はないのでGOTOかWHILE　WENDへ変更すること
2280 '
2290 *NEXT1
2300  CT02%=0:NUL0$=""
2310  *LOOP2A
2320   LINE INPUT #3,NUL0$
2330   IF KINSTR(NUL0$,"[")>0 THEN *NEXT2
2340   MBD0$(CT02%)=NUL0$
2350   CT02%=CT02%+1
2360  GOTO *LOOP2A
2370 '
3000 *NEXT2
3010 'WSAI-DATA LOGGER DATA I/F
3020  PRINT CSV0$+"LOG2.LOG"
3030  OPEN CSV0$+"LOG2.LOG" FOR APPEND AS #1
3040  OPEN "COM1:N81NN" AS #2:'        NONPARI,DATA8BIT,STOP1BIT,NONXON,NONSPARA  
3041  'OPEN "c:\log\TEST.DAT" AS #2    'DataLoggerがないのでチェック用
3050  PRINT #2,"T";'                      COMMAND-T(DATA転送)送出
3060  LINE INPUT #2,NUL0$:'                    COMMAND ECHOの削除
3070 '
3080 *LOOP1
3090  LINE INPUT #2,DLD0$:'               DATA受信
3100  PRINT DLD0$:'                       DATA画面表示
3110  PRINT #1,DLD0$
3120   IF DLD0$<>"" THEN *LOOP1:'         NOTDATAEND GOTO *LOOP1
3130  CLOSE #1
3140  PRINT #2,"C";
3150  CLOSE #2
3160 ' RENAME 
3170  DID0$=DATE$:DIT0$=TIME$
3180  DNC0$=HED0$+"-"+DIF0$+"-"
3190  DIF0$=LEFT$(DID0$,2)+MID$(DID0$,4,2)+MID$(DID0$,7,2)
3200  DIF0$=DIF0$+LEFT$(DIT0$,2)+MID$(DIT0$,4,2)
3210  DNC0$=DNC0$+DIF0$
3220  PRINT DNC0$
3230  NAME CSV0$+"LOG2.LOG" AS DNC0$+".CSV"
4000 'BECKY I/F
4010  CT00%=0
4020  OPEN BCY0$+"USER0\OUTBOX.MBX" FOR INPUT AS #1
4030  OPEN BCY0$+"USER0\OUTBOX.TMP" FOR OUTPUT AS #2
4040  WHILE EOF(1)=0
4050   LINE INPUT #1,DMY0$
4060    IF INSTR(DMY0$,".")>0 THEN CT00%=CT00%+1
4070   PRINT #2,DMY0$
4080  WEND
4090  PRINT #2,"FROM:"+MFR0$
4100  PRINT #2,"TO:"+MFR0$
4110  PRINT #2,"BCC:";
4120  FOR CT03%=0 TO CT01%-1
4130   PRINT #2,MTO0$(CT03%)
4140  NEXT CT03%
4150  PRINT #2,"SUBJECT:"+DNC0$
4160  PRINT #2,"X-PRIORITY:3"
4170  PRINT #2,"STATUS:RW"
4180  PRINT #2,"X-BECKY-ATTACHMENT-FILE:"+CSV0$+DNC0$+".CSV"
4190  PRINT #2,""
4200  FOR CT03%=0 TO CT02%-1
4210   PRINT #2,MBD0$(CT03%)
4220  NEXT CT03%
4230  PRINT #2,""
4240  PRINT #2,"."
4250  PRINT #2,""
4260  CLOSE
4270  KILL BCY0$+"USER0\OUTBOX.$$$"
4280  NAME BCY0$+"USER0\OUTBOX.MBX" AS "OUTBOX.$$$"
4290  NAME BCY0$+"USER0\OUTBOX.TMP" AS "OUTBOX.MBX"
4310  CT00$=STR$(CT00%+1)
4320  KILL BCY0$+"USER0\OUTBOX.CTL"
4330  OPEN BCY0$+"USER0\OUTBOX.CTL" FOR OUTPUT AS #1
4340  PRINT #1,"[TREE]"
4350   PRINT #1,"EXPANDED=0"
4360   PRINT #1,""
4370   PRINT #1,"[MAIL]"
4380   PRINT #1,"TOTAL="+CT00$
4390   PRINT #1,"UNREAD="+CT00$
4400  PRINT #1,""
4410  CLOSE
4420 *LOOP2
4421   print "end"
4430   IF INKEY$<>CHR$(&HD) THEN *LOOP2:' NOTRETURN GOTO *LOOP2
4450  END